System

lhs=(z^3)-1; (* left-hand side of the lhs=0 equation *)
iter=((#-(lhs/(D[lhs,z])))/.z->#)&; (* Newton's method iteration (Subscript[z, n])->(Subscript[z, n+1]) *)

Example 1
(first three iteration steps)

iter@(3.+I)
iter@iter@(3.+I)
iter@iter@iter@(3.+I)

Example 2
(repeated iteration steps: the value converges to the -(1/2)-((Sqrt[3])/2)i root after ~25 steps)

list=NestList[iter,.003+0.01I,100];
ListLinePlot[ReIm[list]\[Transpose]]  (* plots for real and imaginary parts *)

Diagram

Definitions

a=2.; (* plot region half-size *)
res=200; (* resolution, px *)
z0=Table[re+I im,{im,a(1-(1/res)),-a(1-(1/res)),-((2a)/res)},{re,-a(1-(1/res)),a(1-(1/res)),((2a)/res)}]; (* complex plane grid *)
roots=z/.NSolve[lhs==0,z,Complexes];(* set of the equation roots *)

Complex plane coloring function
(color: z->RGBColor)

color[z_]:=(colorset={,,}; (* colors for each of the equation roots *)
C∞=ComplexInfinity;If[Count[#,C∞]>0,
colorset[[Position[#,C∞][[1,1]]]](* edge case (immediate vicinity of either of the roots) *),
Blend[colorset,#](* general case (resulting color = weighted sum of the root colors) *)]&@(((Max[#,(10^(-10))])^(-1))(* root weights (inverse distance to a root) *)&/@Abs[z-roots]));

Example 3
(colors of various complex points)

color[1]
color/@{I,0,-.5-I}

Example 4
(initial coloring: color centers = roots )

Image@Map[color,z0,{2}]

Example 5
(coloring after 5 iteration steps)

z5=Quiet@Map[Nest[iter,N[#],5]&,z0,{2}];
Image@Map[color,z5,{2}]

Newton Basins
(iteration steps -> ∞)

z∞=Quiet@Map[Nest[iter,N[#],50 (* ≳ number from example 2 *)]&,z0,{2}];
Image@Map[color,z∞,{2}]

Animation

zlist=Transpose[Quiet@Map[NestList[iter,N[#],50 ]&,z0,{2}],{2,3,1}];
imglist=Image[Map[color,#,{2}]]&/@zlist;

ListAnimate[imglist]